mirror of
https://github.com/llvm/llvm-project.git
synced 2025-04-25 02:56:05 +00:00
61f471a705
Based on mgorny@'s D67890 There are 3 places where python site-package path is calculated independently: 1. finishSwigPythonLLDB.py where files are written to site-packages. 2. lldb/scripts/CMakeLists.txt where site-packages are installed. 3. ScriptInterpreterPython.cpp where site-packages are added to PYTHONPATH. This change creates the path once and use it everywhere. So that they will not go out of sync. Also it provides a chance for cross compiling users to specify the right path for site-packages. Subscribers: lldb-commits Tags: #lldb Differential Revision: https://reviews.llvm.org/D68442 llvm-svn: 373991
58 lines
1.5 KiB
CMake
58 lines
1.5 KiB
CMake
file(GLOB SWIG_INTERFACES interface/*.i)
|
|
file(GLOB_RECURSE SWIG_SOURCES *.swig)
|
|
file(GLOB SWIG_HEADERS
|
|
${LLDB_SOURCE_DIR}/include/lldb/API/*.h
|
|
${LLDB_SOURCE_DIR}/include/lldb/*.h
|
|
)
|
|
file(GLOB SWIG_PRIVATE_HEADERS
|
|
${LLDB_SOURCE_DIR}/include/lldb/lldb-private*.h
|
|
)
|
|
foreach(private_header ${SWIG_PRIVATE_HEADERS})
|
|
list(REMOVE_ITEM SWIG_HEADERS ${private_header})
|
|
endforeach()
|
|
|
|
if(LLDB_BUILD_FRAMEWORK)
|
|
set(framework_arg --framework --target-platform Darwin)
|
|
endif()
|
|
|
|
find_package(SWIG REQUIRED)
|
|
set(SWIG_MIN_VERSION "2.0.0")
|
|
if (${SWIG_VERSION} VERSION_LESS ${SWIG_MIN_VERSION})
|
|
message(FATAL_ERROR "LLDB requires swig ${SWIG_MIN_VERSION}, your version is ${SWIG_VERSION}.")
|
|
endif()
|
|
|
|
if(APPLE)
|
|
set(DARWIN_EXTRAS "-D__APPLE__")
|
|
else()
|
|
set(DARWIN_EXTRAS "")
|
|
endif()
|
|
|
|
add_custom_command(
|
|
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
|
|
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lldb.py
|
|
DEPENDS ${SWIG_SOURCES}
|
|
DEPENDS ${SWIG_INTERFACES}
|
|
DEPENDS ${SWIG_HEADERS}
|
|
COMMAND ${SWIG_EXECUTABLE}
|
|
-c++
|
|
-shadow
|
|
-python
|
|
-features autodoc
|
|
-threads
|
|
-I${LLDB_SOURCE_DIR}/include
|
|
-I${CMAKE_CURRENT_SOURCE_DIR}
|
|
-D__STDC_LIMIT_MACROS
|
|
-D__STDC_CONSTANT_MACROS
|
|
${DARWIN_EXTRAS}
|
|
-outdir ${CMAKE_CURRENT_BINARY_DIR}
|
|
-o ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
|
|
${LLDB_SOURCE_DIR}/scripts/lldb.swig
|
|
VERBATIM
|
|
COMMENT "Builds LLDB Python wrapper")
|
|
|
|
add_custom_target(swig_wrapper ALL DEPENDS
|
|
${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
|
|
${CMAKE_CURRENT_BINARY_DIR}/lldb.py
|
|
)
|
|
|